時折、解析的に解けない形状の電気抵抗を求めなければならないことがあって、 有限要素法で、注1の定常電流場の方程式から電流密度分布を求め、 全発熱量を計算して、電気抵抗を求めることもできますが、 既に解説したキャパシタンスを利用する方法のほうが簡単です。
二次元の定常電流場では静電場と同様に、電位に関するラプラス方程式
(d/dx+d/dy)(g*(d/dx+d/dy)(V)) = 0 ここに、 V = 電位 (V) g = 導電率 (S/m)が成立ちますから、上記のラプラス方程式を解いて、ジュール熱で失われるエネルギ
W = σ*∫*E^2*dV ここに、 W = ジュール熱で失われるエネルギ (J/s) σ = 導電率 (S/m) σ = 導電率 (S/m) E = 電界の強さ (V/m) = -grad(V) ∫f(v)*dV = f(v) の体積積分を求め、電気抵抗
R = ΔV^2 / W ここに、 R = 電気抵抗 (Ω) ΔV = 電極間電位差 (V)を求めることができます。
上記の計算は静電界のキャパシタンス計算と極めてよく似ていますが、 その理由は注1に述べる定常電流場と静電場の対応関係 にあります。
無限に広がる一様な導電物質中の導体間抵抗の場合は、 直流の電気抵抗とキャパシタンスの間に下記の簡単かつ重要な関係が成立します。 (注2)
R * C = ε / σ (3.1) ここに、 R = 電気抵抗 (Ω/m) C = キャパシタンス (F/m) ε = 誘電率 (F/m) σ = 導電率 (S/m)
つまり、電気抵抗の計算は
誘電率 ε の単位が F/m、導電率 σ の単位が S/m、 Ω/m = m/S であることに注意してください。 キャパシタンスに蓄えられるエネルギが 電気抵抗で失われるジュール熱のエネルギに対応します。
以下の例では、電流の向きが等電位線に直交していることに注意してください。
5D-2V 同軸ケーブルの寸法で、 絶縁体の導電率 8.77e-12 G/m の電気抵抗を求めると、 次ぎのようになります。
/* coaxial cable: same size as 5C-2V */
a1:=0.4; /* inner conductor raius */
a2:=2.45; /* outer conductor radius */
rho:=8.77e-12; /* conductivity */
border(1,0,2*pi,120) { x:=a2*cos(t); y:=a2*sin(t) };
border(2,0,2*pi,20) { x:=a1*cos(-t); y:=a1*sin(-t) };
buildmesh(5000);
v1:=0.0; v2:=1.0;
solve(v) {
onbdy(1) v = v1;
onbdy(2) v = v2;
pde(v) -laplace(v) = 0;
};
plot(v);
u=rho*(dx(v)*dx(v)+dy(v)*dy(v)); /* Joul heat loss */
u1:=intt[u];
r:=(v2-v1)*(v2-v1)/u1; /* Ohm*m */
printf("R = %.2e (Ohm*m)\n", r);
計算結果は 3.33e10 Ω/m ですが、
この場合は、全空間が同じ誘電体で満たされていますから、
5C-2V 同軸ケーブル(誘電率 2.036e-11 F/m, キャパシタンス 69.8e-12 F/m)
で満たされていますから、
3.1 式の関係が成立して、
R = ε / σ / C = 2.036e-11 / 8.77e-12 / 69.8e-12 = 3.33e10と、直接求めた場合と一致します。
長さ無限大の 1mx2m 長方形断面の角柱の 1m 側面間の抵抗を求めます。 薄板の場合も厚さを考慮すれば同じです。 2, 3 の境界を淵いっぱいまで確保するために、 border() 記述で 2, 3 を先に書いていることに注意して」ください。
/* rectangile conductor */
rho:=5.76e7; /* annealed copper */
border(2,0,1,10) { x:= 2; y:= t };
border(3,0,1,10) { x:= 0; y:= 1-t };
border(1,0,2,20) { x:= t; y:= 0 };
border(1,0,2,20) { x:= 2-t; y:= 1 };
buildmesh(400);
v1:=0.0; v2:=1.0;
solve(v) {
onbdy(2) v = v1;
onbdy(3) v = v2;
pde(v) -laplace(v) = 0;
};
plot(v);
u=rho*(dx(v)*dx(v)+dy(v)*dy(v)); /* Joul heat loss */
u1:=intt[u];
r:=(v2-v1)*(v2-v1)/u1; /* Ohm*m */
printf("R = %.2e (Ohm*m)\n", r);
単位長あたりでは、断面積 1 m^2、長さ 2 m の電気抵抗ですから、
R = 2 / (5.76e7 * 1) = 3.47e-08 Ωになります。
次に中央に切り欠きを作るとどうなるかを計算してみます。
/* rectangile conductor with cutout */
rho:=5.76e7;
border(2,0,1,10) { x:= 2; y:= t };
border(3,0,1,10) { x:= 0; y:= 1-t };
border(1,0,0.9,10) { x:= t; y:= 0 };
border(1,0,0.4,10) { x:= 0.9; y:= t };
border(1,0,0.2,5) { x:= 0.9+t; y:= 0.4 };
border(1,0,0.4,10) { x:= 1.1; y:= 0.4-t };
border(1,1.1,2,10) { x:= t; y:= 0 };
border(1,0,0.9,10) { x:= 2-t; y:= 1 };
border(1,0,0.4,10) { x:= 1.1; y:= 1-t };
border(1,0,0.2,5) { x:= 1.1-t; y:= 0.6 };
border(1,0,0.4,10) { x:= 0.9; y:= 0.6+t };
border(1,0,0.9,10) { x:= 0.9-t; y:= 1 };
buildmesh(400);
v1:=0.0; v2:=1.0;
solve(v) {
onbdy(2) v = v1;
onbdy(3) v = v2;
pde(v) -laplace(v) = 0;
};
plot(v);
u=rho*(dx(v)*dx(v)+dy(v)*dy(v)); /* Joul heat loss */
u1:=intt[u];
r:=(v2-v1)*(v2-v1)/u1; /* Ohm*m */
printf("R = %.2e (Ohm/m)\n", r);
1x1x0.9 のブロック 2 個と 1x0.2x0.2 のブロック 1 個の単純な直列抵抗なら
4.86e-8 Ωですから、
切り欠きによる電流集中で、電気抵抗は 1.29 倍になることがわかります。
接点などの接触部分では、こういった電流集中がたくさん発生します。
絶縁抵抗の低い絶縁体で作成した VHF フィーダの電気抵抗を求めてみます。
/* VHF feeder code (JIS C 3330 1VHF) */
pi2:=2*pi; a1:=0.345; a2:=0.75; s1:=(9 - 1.5)/2; h1:=1/2; a3:=20;
rho:=8.77e-12;
y1:=h1; x1:=sqrt(a2*a2 - h1*h1);
t1:=atan(y1/x1);
x1:=s1-x1;
border(2,0,pi2,20) { x:=a1*cos(-t)+s1; y:=a1*sin(-t) };
border(3,0,pi2,20) { x:=a1*cos(-t)-s1; y:=a1*sin(-t) };
border(1,0,4*pi-4*t1+6,100) {
if (t<=2*pi-2*t1) then {
p1:=t+t1; x:=a2*cos(p1)-s1; y:=a2*sin(p1)
}
else if (t<=2*pi-2*t1+3) then {
p1:=t-(2*pi-2*t1);
x:=-x1+2*x1/3*p1; y:=-h1
}
else if (t<=4*pi-4*t1+3) then {
p1:=t-(pi2-2*t1+3)+t1-pi;
x:=a2*cos(p1)+s1; y:=a2*sin(p1)
}
else {
p1:=t-(4*pi-4*t1+3);
x:=x1-2*x1/3*p1; y:=h1
}
};
buildmesh(10000);
v1:=0.5;
solve(v) {
onbdy(2) v = v1;
onbdy(3) v = -v1;
pde(v) -laplace(v) = 0;
};
plot(v);
u=rho*(dx(v)*dx(v)+dy(v)*dy(v)); /* electro static energy for air */
u1:=intt[u];
r:=2*v1/u1; /* Ohm*m */
printf("R = %.2e (Ohm*m)\n", r);
4芯ケーブルの導体・シールド間電気抵抗を求めてみます。 隣接導体の絶縁体経由の電流は無視できるものとしています。
/* shielded 4 conductor cable */
rho:=8.77e-12; /* insulation */
a1:=1;
a2:=2;
border(1,0,pi/2,10) { x:= a2*cos(t); y:=a2*sin(t) };
border(2,pi/2,2*pi,30) { x:=a2*cos(t); y:=a2*sin(t) };
border(3,0,2*pi,20) { x:=a1*cos(t); y:=a1*sin(t) };
buildmesh(400);
v1:=0.0; v2:=1.0;
solve(v) {
onbdy(1) v = v2;
onbdy(3) v = v1;
pde(v) -laplace(v) = 0;
};
plot(v);
u=rho*(dx(v)*dx(v)+dy(v)*dy(v)); /* Joul heat loss */
u1:=intt[u];
r:=(v2-v1)*(v2-v1)/u1; /* Ohm*m */
printf("R = %.2e (Ohm*m)\n", r);
定常電流場は
E = -grad(V) J = σ*E div(J) = 0 ここに、 E = 電界強度 (V/m) V = 電位差 (V) J = 電流密度 (A/m^2) σ = 導電率 (S/m)静電場は
E = -grad(V) D = ε*E div(D) = ρ ここに、 D = 電束密度 (C/m^2) ε = 誘電率 (F/m)ですから、定常電流場と静電場には下記の対応があります。
ε <-> σ D <-> J
4.2. 注2 -無限に広がる一様な導電物質中の導体間抵抗とキャパシタンスの関係
今、無限に広がる誘電率 ε の空間内に、二つの導体があったとして、 その導体間キャパシタンスを C とします。 次に、この誘電体を導電率 σ の導電物質で置き換えて、 導体間の電気抵抗を R とすれば、 キャパシタンスに対応する電気力線の分布と、 電気抵抗に対応する電流線の分布は一致します。
一方の導体から流出する電流の強さ I は、 その導体を囲む任意の閉局面 S に於ける J, E の法線方向面積分から
I = ∫J*dS = σ*∫E*dSまた、キャパシタンスに対応する電極上の電荷 Q も同様に
Q = ε*∫E*dS
これらを電気回路の関係
R = V / I Q = C * Vに代入すれば
R = (ε / σ) / Cが得られます。
平林 浩一, 2015-05-22