伝送線路のSPICEモデルとケーブルイコライザ(Cable Equalizer)

長距離ケーブルのパルス伝送ではケーブル導体の渦電流に起因する位相歪による ケーブル特有の伝送歪が大きな問題になって、 この歪の補正にイコライザ(equalizer)が使われることが多く、 そのメカニズムを解説してみます。

私自身は昔からUnixしか使いませんので、 この解説に出てくるspicereduceも、(私自身が毎日使っている) FreeBSDで動くopen domainのソフトウェアです。 Linuxでも同じ環境が作れると思います。

1. 定抵抗回路とイコライザ

1図の回路で

  Z1 * Z2 = R^2
  ここに、
	Z1, Z2 = 任意のインピーダンス
	R = 純抵抗 (Ω)
が成り立つとき、端子 1-2 間のインピーダンスは純抵抗 R定抵抗回路(constant-resistance circuit)となり、 Z1 と Z2 は R に関して互いに逆回路(Inverse network)であると言います。 (注1)

1図 定抵抗回路にできる回路の一つ

この最も簡単な場合が2図の回路で、

  L/C = R^2
の関係が成り立つとき定抵抗になります。 (注2)

2図 - 簡単な定抵抗回路の例

つまり、2図の回路は単一の抵抗 R と等しいわけですが、 端子 1 - 2 間は積分回路、端子 2 - 3 は微分回路になっていて、 この積分と微分が打ち消し合う条件が L/C = R^2 というわけです。

この回路のStep応答を回路シミュレータSPICEで確認してみると、 次ぎのようになります。(注3)

2図 - 1図の回路のステップ応答

v(3) が R//L 回路のステップ応答、v(5) が R//C 回路のステップ応答、 v(8) が R//L と R//C を直列接続した1図の回路のステップ応答です。 v(3) が積分動作、v(5) が微分動作になっていて、 直列接続すると、両者が打ち消し合って無歪波形 V(8) になることがわかります。 (記号「//」は並列接続を意味します。)

ここで、 2図の回路を端子 1-2 間の R//L 回路の伝送歪を端子 2-3 間の R//C 回路で補正したと見ると、 イコライザ(等価器)(Equalizer)の概念が生まれます。

複数の素子からなる回路の逆回路を求める手続きは次ぎのとおりです。

  1. 直列接続は並列接続に、並列接続は直列接続に入れ換える
  2. 抵抗 R1 は R/R1 で置き換える
  3. インダクイタンス L は C (=L/R^2) で置き換える
  4. キャパシタンス C は L (=C*R^2) で置き換える

2. ケーブル伝送の等価回路

ケーブル伝送の場合は、

  1. ケーブルの長さと速度係数による遅延
  2. ケーブル導体の渦電流損失(抵抗)と内部インダクタンスの周波数特性による位相歪
の二つが問題になりますが、伝送波形に歪を与えるのは後者だけで、 電気回路としての理解には 3図の等価回路がわかりやすいと思います。

3図 ケーブル導体の渦電流損失と内部インダクタンス

この等価回路の解説は http://www.mogami.com/paper/spice-tline/spice-tline.htmlをご欄ください。

R1 が導体表面、Rm, Lm が導体中心部に対応します。 周波数が低いと電流が中心部まで流れ、 周波数が高くなるに従って表面しか流れなくなりますが、 これが表皮効果の仕組みです。

3図の R1 を除く部分の逆回路を作ると、4図のようになります。

  rM = Rm-1^2 / (Rm + Rm-1)
  cM = Lm / Rm-1^2
  ..

4図 - 3図の R1 と並列な部分の逆回路

3図の Rm, Lm が1図の Z1、Rm-1 が1図の R に対応しますので、 この部分を逆回路に変換し、 次ぎに、Lm-1 と Rm-2 を逆回路に変換と、 再帰的に変換を続けると4図が得られますが、 この回路は、 周波数が高いと導体中心部の補償に対応する rM, rM-1, .. が cM, cM-1, .. で短絡されて R1 だけになり、 周波数が低くなるに従って残りの抵抗が効いてくるという、 表皮効果とは逆の特性になります。

これを R1 に並列接続すればケーブル・イコライザが作れますが、 イコライザの素子はケーブルとケーブル長に合わせて決めなければならず、 波形の精度が必要とか、伝送速度が速くなると、必要な素子数が増えます。

しかし、デジタル伝送のパルス信号であれば、 基本波の 5 倍から 7 倍の高調波までを、ある程度補償すれば十分なので、 比較的少ない素子でイコライザを作ることができて、 ここでは、AES3(degitak audio) 規格の5C2V同軸ケーブル用に規定された イコライザを解説します。

3. AES3 のイコライザ

以下、 AES3-2id-2012(AES information document for digital audio engineering - Guidelines for the use of the AES3 interface)の 5C-2V同軸ケーブル 1,000 m とType I equalizerの組み合わせを SPICEでシミュレーションしてみると5図のようになります。 (注4)

5図 5C-2V 1,000 m と Type I equalizer の組み合わせ

v(1) が同軸ケーブル入力端の波形、v(3) が同軸ケーブル出力端の波形、 v(4) がイコライザ補正後の波形です。 V(1) は 1 km 先の受端波形と比べやすいようにスケーリングしてありますが、 同軸ケーブルで大幅に立上りの遅くなった波形が、 かなり復元されていることがわかります。

実際の受信器ではイコライザの直後に交流アンプを設置して直流分をカットします。

このイコライザの周波数特性は6図のようになっています。 (注5)

6図 Type I equalizer の周波数特性

0.2 MHz あたりから 20 MHz あたりの帯域で、 およそ(ケーブル特有の周波数特性である)周波数の平方根に比例する 程度の特性になるように設計してありますが、 これは 48 kHz サンプリングの AES 信号のスペクトルがそのあたりに存在するためで、 SPICEで AES 信号のスペクトルを調べてみると、 7図のようになります。 (注6)

Fourier analysis for v(1):
  No. Harmonics: 10, THD: 38.1827 %, Gridsize: 200, Interpolation Degree: 1

Harmonic Frequency   Magnitude   Phase       Norm. Mag   Norm. Phase
-------- ---------   ---------   -----       ---------   -----------
 0       0           -0.017984   0           0           0          
 1       3.072e+06   3.79663     -178.1      1           0
 2       6.144e+06   0.0350885   -88.619     0.00924201  89.4813
 3       9.216e+06   1.20501     -174.3      0.31739     3.80051
 4       1.2288e+07  0.0325311   -87.448     0.00856841  90.6521
 5       1.536e+07   0.653579    -170.49     0.172147    7.60598
 6       1.8432e+07  0.0285387   -86.767     0.00751685  91.3334
 7       2.1504e+07  0.39794     -166.68     0.104814    11.4201
 8       2.4576e+07  0.0234922   -87.046     0.00618763  91.055
 9       2.7648e+07  0.245509    -162.85     0.0646649   15.2469

7図 AES 信号のスペクトル

およそ 3.07 MHz の基本波から 7 倍高調波の 22 MHz あたりまでのスペクトルが 補正できれば、元波形にかなり近付けることがわかります。

このスペクトル上限は、良く知られた目の子則(rule of thumb)

  Fmax = 0.35/Tr

  ここに、Tr = パルスの立上り時間 (S)
          Fmax = 最も高い周波数成分 (Hz)
から見当を付けることもできて、 例えば、立上り時間を 20 nS とすれば 17.5 MHz が得られます。

4. 最近の傾向

イコライザは人類にとって長年のの一つで、 1950 年代から(この分野のアイデアの黄金時代とも思える) 1980 年にかけて 基本的なアイデアが煮詰まってゆきましたが、 IEEEE Xplore で equalization を検索するだけでも、 この 1860-1980 年間で 11,000 件の文献が出て来るそうです。 (注7)

さらに、その後の LSI の進歩により、 現在では、多くの半導体メーカーから、 いろいろな用途に適したイコライザが製品化され、 安価な銅ケーブルによる高速長距離伝送が可能になっていて、 ケーブル長に自動適合する製品もあります。

5. 注

5.1. 注1 - 定抵抗回路

定抵抗回路は、これ以外にもあって、 波形を変えずに遅延だけを目的とする位相回路も、よく知られています。 ここで1図の定抵抗回路を選んだのは、 この後、ケーブル・イコライザを考えるためです。 この分野の勉強には、 回路理論とか伝送回路理論の教科書を見てください。 定抵抗回路には逆回路が不可欠です。

5.2. 注2 - 2図のインピーダンス計算

2図の端子 1 - 3 間インピーダンスは

  1/(1/(j*ω*L)+1/R) + 1/(j*ω*C + 1/R))
ですから手計算でも簡単ですが、 数式処理プログラムReduceを使って不精すると、下記のようになります。
$ reduce
REDUCE 3.8, 15-Apr-04 ...

1: l:=c*r^2;

        2
l := c*r

2: 1/(1/(i*w*l)+1/r)+1/(i*w*c+1/r);

r

3: bye;
$ 

1図の回路だと、

  1 / (1 / Z1 + 1 / R) + 1 / (1 / Z2 + 1 / R)
  Z1 * Z2 = R^2
ですが、この程度でもreduceのような数式計算プログラムを使うほうが、 速くて間違いも少ないです。

5.3. 注3 - 2図の計算に使ったSPICEの command script

Inverse circuit
.SUBCKT RL 1 2
R 1 2 100
L 1 2 10MH
.ENDS RL
.SUBCKT RC 1 2
R 1 2 100
C 1 2 1UF
.ENDS RC
VIN 1 0 PULSE(0 1 0 .2NS .2NS 1S 2S)
R1 1 2 100
X1 2 3 RL
R2 3 0 100
R3 1 4 100
X2 4 5 RC
R4 5 0 100
R5 1 6 100
X3 6 7 RL
X4 7 8 RC
R6 8 0 100
.control
tran 1u 1MS 0 1u
plot v(3) v(5) v(8)
.endc
.END

5.4 注4 - AES3-2id-2012 の 5C-2V 1,000 m と Type I equalizer の組み合わせ

5図のシミュレーションのSPICEscript は次ぎのとおりです。

AES/EBU simulation
* 5C-2V 1000m
.SUBCKT TLINE 1 2
R1 1 2 5025.04
L2 2 3 3.30601e-06
R2 1 3 2512.52
L3 3 4 7.01967e-06
R3 1 4 1256.26
L4 4 5 1.60247e-05
R4 1 5 628.13
L5 5 6 4.4949e-05
R5 1 6 314.065
.ENDS TLINE
* AES3 Tyoe I equalizer
.SUBCKT EQUALIZER1 1 2
R1 1 3 100
L1 3 0 12uH
R2 1 2 220
C1 1 2 2200pF
R3 2 0 75
.ENDS EQUALIZER
VIN 1 0 PULSE(0 1 0 20NS 20NS 142NS 326NS)
RS  1 2 110
X1  2 3 TLINE
X2  3 4 EQUALIZER1
.control
tran 10n 400n
plot v(1)*0.2 v(3) v(4)
.endc
.END

1,000 m 以外の長さに対する応答がほしい場合は、 SUBCKT(SUBCIRCUIT) の R1, L2, R2, L3, R3, L4, R4, L5, R5 の値を長さに比例した値に書き換えます。

SUBCKT(SUBCIRCUIT) のパラメータは http://www.mogami.com/cad/spice-tline.html で求めることができます。 理論的説明は http://www.mogami.com/paper/spice-tline/spice-tline.html にあります。

なお、AESType II equalizerの回路は次のとおりです。

AES3 Type II equalizer
.SUBCKT EQUALIZER2 1 2
R1 1 3 75
R2 3 4 56
L1 4 0 270uH
R3 3 5 30
L2 5 0 5.6uH
R4 1 6 180
C1 1 6 1000pF
R5 6 2 100
C2 6 2 47000pF
R6 2 0 75
.ENDS EQUALIZER2

5.5 注5 - 6図のSPICE script

6図のSPIE script は次ぎのとおりです。

AES/EBU Type 1 eqalizer
.SUBCKT EQUALIZER1 1 2
R1 1 3 100
L1 3 0 12uH
R2 1 2 220
C1 1 2 2200pF
R3 2 0 75
.ENDS EQUALIZER
VIN 1 0 AC 1V
R1 1 2 75
X1 2 3 EQUALIZER1
.control
ac dec 100 10K 100MEG
plot V(3)
.endc
.END

5.6 注6 - AES 信号のスペクトル解析

7図のSPICE script は次ぎのとおりです。

AES/EBU simulation
* run with "spice -b this_script"
VIN 1 0 PULSE(-3 3 0 20NS 20NS 142NS 326NS)
RS  1 2 75
RT  2 0 75
.control
tran 10n 500n
fourier 3.072Meg v(1)
.endc
.END

5.7 注7 - イコライザの歴史 1860-1980

  David Failconer,- History of Equalization 1860-1980
	IEEE Communications Magazine, October 2011, pp.42-49
この最後の 1980 年がVLSI時代の幕開けになります。 この解説ではふれていない、 周波数領域でのイコライジング技術など、 いろいろな手法がありますので、こういった資料も一読をお奨めします。 インタネットで自由に見られます。

なお、この年代以降でも、実に多くの文献、特許があって、例えば、 PHILIPS の特許(FIG.2)では、 4図の回路と同じものを反転増幅器を使うことで、 3図の L を C で置き換えたネットワークで実現しています。

平林 浩一, 2015-08-14